perlfunc - phpMan

PERLFUNC(1) Perl Programmers Reference Guide PERLFUNC(1)

NAME
perlfunc - Perl builtin functions

DESCRIPTION
The functions in this section can serve as terms in an expression. They fall into
two major categories: list operators and named unary operators. These differ in
their precedence relationship with a following comma. (See the precedence table in
perlop.) List operators take more than one argument, while unary operators can
never take more than one argument. Thus, a comma terminates the argument of a
unary operator, but merely separates the arguments of a list operator. A unary
operator generally provides a scalar context to its argument, while a list operator
may provide either scalar or list contexts for its arguments. If it does both, the
scalar arguments will be first, and the list argument will follow. (Note that
there can ever be only one such list argument.) For instance, splice() has three
scalar arguments followed by a list, whereas gethostbyname() has four scalar argu-
ments.

In the syntax descriptions that follow, list operators that expect a list (and pro-
vide list context for the elements of the list) are shown with LIST as an argument.
Such a list may consist of any combination of scalar arguments or list values; the
list values will be included in the list as if each individual element were inter-
polated at that point in the list, forming a longer single-dimensional list value.
Elements of the LIST should be separated by commas.

Any function in the list below may be used either with or without parentheses
around its arguments. (The syntax descriptions omit the parentheses.) If you use
the parentheses, the simple (but occasionally surprising) rule is this: It looks
like a function, therefore it is a function, and precedence doesn’t matter. Other-
wise it’s a list operator or unary operator, and precedence does matter. And
whitespace between the function and left parenthesis doesn’t count--so you need to
be careful sometimes:

print 1+2+4; # Prints 7.
print(1+2) + 4; # Prints 3.
print (1+2)+4; # Also prints 3!
print +(1+2)+4; # Prints 7.
print ((1+2)+4); # Prints 7.

If you run Perl with the -w switch it can warn you about this. For example, the
third line above produces:

print (...) interpreted as function at - line 1.
Useless use of integer addition in void context at - line 1.

A few functions take no arguments at all, and therefore work as neither unary nor
list operators. These include such functions as "time" and "endpwent". For exam-
ple, "time+86_400" always means "time() + 86_400".

For functions that can be used in either a scalar or list context, nonabortive
failure is generally indicated in a scalar context by returning the undefined
value, and in a list context by returning the null list.

Remember the following important rule: There is no rule that relates the behavior
of an expression in list context to its behavior in scalar context, or vice versa.
It might do two totally different things. Each operator and function decides which
sort of value it would be most appropriate to return in scalar context. Some oper-
ators return the length of the list that would have been returned in list context.
Some operators return the first value in the list. Some operators return the last
value in the list. Some operators return a count of successful operations. In
general, they do what you want, unless you want consistency.

A named array in scalar context is quite different from what would at first glance
appear to be a list in scalar context. You can’t get a list like "(1,2,3)" into
being in scalar context, because the compiler knows the context at compile time.
It would generate the scalar comma operator there, not the list construction ver-
sion of the comma. That means it was never a list to start with.

In general, functions in Perl that serve as wrappers for system calls of the same
name (like chown(2), fork(2), closedir(2), etc.) all return true when they succeed
and "undef" otherwise, as is usually mentioned in the descriptions below. This is
different from the C interfaces, which return "-1" on failure. Exceptions to this
rule are "wait", "waitpid", and "syscall". System calls also set the special $!
variable on failure. Other functions do not, except accidentally.

Perl Functions by Category

Here are Perl’s functions (including things that look like functions, like some
keywords and named operators) arranged by category. Some functions appear in more
than one place.

Functions for SCALARs or strings
"chomp", "chop", "chr", "crypt", "hex", "index", "lc", "lcfirst", "length",
"oct", "ord", "pack", "q/STRING/", "qq/STRING/", "reverse", "rindex",
"sprintf", "substr", "tr///", "uc", "ucfirst", "y///"

Regular expressions and pattern matching
"m//", "pos", "quotemeta", "s///", "split", "study", "qr//"

Numeric functions
"abs", "atan2", "cos", "exp", "hex", "int", "log", "oct", "rand", "sin",
"sqrt", "srand"

Functions for real @ARRAYs
"pop", "push", "shift", "splice", "unshift"

Functions for list data
"grep", "join", "map", "qw/STRING/", "reverse", "sort", "unpack"

Functions for real %HASHes
"delete", "each", "exists", "keys", "values"

Input and output functions
"binmode", "close", "closedir", "dbmclose", "dbmopen", "die", "eof", "fileno",
"flock", "format", "getc", "print", "printf", "read", "readdir", "rewinddir",
"seek", "seekdir", "select", "syscall", "sysread", "sysseek", "syswrite",
"tell", "telldir", "truncate", "warn", "write"

Functions for fixed length data or records
"pack", "read", "syscall", "sysread", "syswrite", "unpack", "vec"

Functions for filehandles, files, or directories
"-X", "chdir", "chmod", "chown", "chroot", "fcntl", "glob", "ioctl", "link",
"lstat", "mkdir", "open", "opendir", "readlink", "rename", "rmdir", "stat",
"symlink", "sysopen", "umask", "unlink", "utime"

Keywords related to the control flow of your perl program
"caller", "continue", "die", "do", "dump", "eval", "exit", "goto", "last",
"next", "redo", "return", "sub", "wantarray"

Keywords related to scoping
"caller", "import", "local", "my", "our", "package", "use"

Miscellaneous functions
"defined", "dump", "eval", "formline", "local", "my", "our", "reset", "scalar",
"undef", "wantarray"

Functions for processes and process groups
"alarm", "exec", "fork", "getpgrp", "getppid", "getpriority", "kill", "pipe",
"qx/STRING/", "setpgrp", "setpriority", "sleep", "system", "times", "wait",
"waitpid"

Keywords related to perl modules
"do", "import", "no", "package", "require", "use"

Keywords related to classes and object-orientedness
"bless", "dbmclose", "dbmopen", "package", "ref", "tie", "tied", "untie", "use"

Low-level socket functions
"accept", "bind", "connect", "getpeername", "getsockname", "getsockopt", "lis-
ten", "recv", "send", "setsockopt", "shutdown", "socket", "socketpair"

System V interprocess communication functions
"msgctl", "msgget", "msgrcv", "msgsnd", "semctl", "semget", "semop", "shmctl",
"shmget", "shmread", "shmwrite"

Fetching user and group info
"endgrent", "endhostent", "endnetent", "endpwent", "getgrent", "getgrgid",
"getgrnam", "getlogin", "getpwent", "getpwnam", "getpwuid", "setgrent", "setp-
went"

Fetching network info
"endprotoent", "endservent", "gethostbyaddr", "gethostbyname", "gethostent",
"getnetbyaddr", "getnetbyname", "getnetent", "getprotobyname", "getprotobynum-
ber", "getprotoent", "getservbyname", "getservbyport", "getservent", "sethos-
tent", "setnetent", "setprotoent", "setservent"

Time-related functions
"gmtime", "localtime", "time", "times"

Functions new in perl5
"abs", "bless", "chomp", "chr", "exists", "formline", "glob", "import", "lc",
"lcfirst", "map", "my", "no", "our", "prototype", "qx", "qw", "readline",
"readpipe", "ref", "sub*", "sysopen", "tie", "tied", "uc", "ucfirst", "untie",
"use"

* - "sub" was a keyword in perl4, but in perl5 it is an operator, which can be
used in expressions.

Functions obsoleted in perl5
"dbmclose", "dbmopen"

Portability

Perl was born in Unix and can therefore access all common Unix system calls. In
non-Unix environments, the functionality of some Unix system calls may not be
available, or details of the available functionality may differ slightly. The Perl
functions affected by this are:

"-X", "binmode", "chmod", "chown", "chroot", "crypt", "dbmclose", "dbmopen",
"dump", "endgrent", "endhostent", "endnetent", "endprotoent", "endpwent", "endser-
vent", "exec", "fcntl", "flock", "fork", "getgrent", "getgrgid", "gethostbyname",
"gethostent", "getlogin", "getnetbyaddr", "getnetbyname", "getnetent", "getppid",
"getprgp", "getpriority", "getprotobynumber", "getprotoent", "getpwent", "getpw-
nam", "getpwuid", "getservbyport", "getservent", "getsockopt", "glob", "ioctl",
"kill", "link", "lstat", "msgctl", "msgget", "msgrcv", "msgsnd", "open", "pipe",
"readlink", "rename", "select", "semctl", "semget", "semop", "setgrent", "sethos-
tent", "setnetent", "setpgrp", "setpriority", "setprotoent", "setpwent", "setser-
vent", "setsockopt", "shmctl", "shmget", "shmread", "shmwrite", "socket", "socket-
pair", "stat", "symlink", "syscall", "sysopen", "system", "times", "truncate",
"umask", "unlink", "utime", "wait", "waitpid"

For more information about the portability of these functions, see perlport and
other available platform-specific documentation.

Alphabetical Listing of Perl Functions

-X FILEHANDLE
-X EXPR
-X A file test, where X is one of the letters listed below. This unary opera-
tor takes one argument, either a filename or a filehandle, and tests the
associated file to see if something is true about it. If the argument is
omitted, tests $_, except for "-t", which tests STDIN. Unless otherwise
documented, it returns 1 for true and ’’ for false, or the undefined value
if the file doesn’t exist. Despite the funny names, precedence is the same
as any other named unary operator, and the argument may be parenthesized
like any other unary operator. The operator may be any of:

-r File is readable by effective uid/gid.
-w File is writable by effective uid/gid.
-x File is executable by effective uid/gid.
-o File is owned by effective uid.

-R File is readable by real uid/gid.
-W File is writable by real uid/gid.
-X File is executable by real uid/gid.
-O File is owned by real uid.

-e File exists.
-z File has zero size (is empty).
-s File has nonzero size (returns size in bytes).

-f File is a plain file.
-d File is a directory.
-l File is a symbolic link.
-p File is a named pipe (FIFO), or Filehandle is a pipe.
-S File is a socket.
-b File is a block special file.
-c File is a character special file.
-t Filehandle is opened to a tty.

-u File has setuid bit set.
-g File has setgid bit set.
-k File has sticky bit set.

-T File is an ASCII text file (heuristic guess).
-B File is a "binary" file (opposite of -T).

-M Script start time minus file modification time, in days.
-A Same for access time.
-C Same for inode change time (Unix, may differ for other platforms)

Example:

while (<>) {
chomp;
next unless -f $_; # ignore specials
#...
}

The interpretation of the file permission operators "-r", "-R", "-w", "-W",
"-x", and "-X" is by default based solely on the mode of the file and the
uids and gids of the user. There may be other reasons you can’t actually
read, write, or execute the file. Such reasons may be for example network
filesystem access controls, ACLs (access control lists), read-only filesys-
tems, and unrecognized executable formats.

Also note that, for the superuser on the local filesystems, the "-r", "-R",
"-w", and "-W" tests always return 1, and "-x" and "-X" return 1 if any
execute bit is set in the mode. Scripts run by the superuser may thus need
to do a stat() to determine the actual mode of the file, or temporarily set
their effective uid to something else.

If you are using ACLs, there is a pragma called "filetest" that may produce
more accurate results than the bare stat() mode bits. When under the "use
filetest ’access’" the above-mentioned filetests will test whether the per-
mission can (not) be granted using the access() family of system calls.
Also note that the "-x" and "-X" may under this pragma return true even if
there are no execute permission bits set (nor any extra execute permission
ACLs). This strangeness is due to the underlying system calls’ defini-
tions. Read the documentation for the "filetest" pragma for more informa-
tion.

Note that "-s/a/b/" does not do a negated substitution. Saying
"-exp($foo)" still works as expected, however--only single letters follow-
ing a minus are interpreted as file tests.

The "-T" and "-B" switches work as follows. The first block or so of the
file is examined for odd characters such as strange control codes or char-
acters with the high bit set. If too many strange characters (>30%) are
found, it’s a "-B" file, otherwise it’s a "-T" file. Also, any file con-
taining null in the first block is considered a binary file. If "-T" or
"-B" is used on a filehandle, the current IO buffer is examined rather than
the first block. Both "-T" and "-B" return true on a null file, or a file
at EOF when testing a filehandle. Because you have to read a file to do
the "-T" test, on most occasions you want to use a "-f" against the file
first, as in "next unless -f $file && -T $file".

If any of the file tests (or either the "stat" or "lstat" operators) are
given the special filehandle consisting of a solitary underline, then the
stat structure of the previous file test (or stat operator) is used, saving
a system call. (This doesn’t work with "-t", and you need to remember that
lstat() and "-l" will leave values in the stat structure for the symbolic
link, not the real file.) (Also, if the stat buffer was filled by a
"lstat" call, "-T" and "-B" will reset it with the results of "stat _").
Example:

print "Can do.\n" if -r $a ││ -w _ ││ -x _;

stat($filename);
print "Readable\n" if -r _;
print "Writable\n" if -w _;
print "Executable\n" if -x _;
print "Setuid\n" if -u _;
print "Setgid\n" if -g _;
print "Sticky\n" if -k _;
print "Text\n" if -T _;
print "Binary\n" if -B _;

abs VALUE
abs Returns the absolute value of its argument. If VALUE is omitted, uses $_.

accept NEWSOCKET,GENERICSOCKET
Accepts an incoming socket connect, just as the accept(2) system call does.
Returns the packed address if it succeeded, false otherwise. See the exam-
ple in "Sockets: Client/Server Communication" in perlipc.

On systems that support a close-on-exec flag on files, the flag will be set
for the newly opened file descriptor, as determined by the value of $^F.
See "$^F" in perlvar.

alarm SECONDS
alarm Arranges to have a SIGALRM delivered to this process after the specified
number of wallclock seconds have elapsed. If SECONDS is not specified, the
value stored in $_ is used. (On some machines, unfortunately, the elapsed
time may be up to one second less or more than you specified because of how
seconds are counted, and process scheduling may delay the delivery of the
signal even further.)

Only one timer may be counting at once. Each call disables the previous
timer, and an argument of 0 may be supplied to cancel the previous timer
without starting a new one. The returned value is the amount of time
remaining on the previous timer.

For delays of finer granularity than one second, you may use Perl’s four-
argument version of select() leaving the first three arguments undefined,
or you might be able to use the "syscall" interface to access setitimer(2)
if your system supports it. The Time::HiRes module (from CPAN, and start-
ing from Perl 5.8 part of the standard distribution) may also prove useful.

It is usually a mistake to intermix "alarm" and "sleep" calls. ("sleep"
may be internally implemented in your system with "alarm")

If you want to use "alarm" to time out a system call you need to use an
"eval"/"die" pair. You can’t rely on the alarm causing the system call to
fail with $! set to "EINTR" because Perl sets up signal handlers to restart
system calls on some systems. Using "eval"/"die" always works, modulo the
caveats given in "Signals" in perlipc.

eval {
local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
alarm $timeout;
$nread = sysread SOCKET, $buffer, $size;
alarm 0;
};
if ($@) {
die unless $@ eq "alarm\n"; # propagate unexpected errors
# timed out
}
else {
# didn’t
}

For more information see perlipc.

atan2 Y,X
Returns the arctangent of Y/X in the range -PI to PI.

For the tangent operation, you may use the "Math::Trig::tan" function, or
use the familiar relation:

sub tan { sin($_[0]) / cos($_[0]) }

bind SOCKET,NAME
Binds a network address to a socket, just as the bind system call does.
Returns true if it succeeded, false otherwise. NAME should be a packed
address of the appropriate type for the socket. See the examples in "Sock-
ets: Client/Server Communication" in perlipc.

binmode FILEHANDLE, LAYER
binmode FILEHANDLE
Arranges for FILEHANDLE to be read or written in "binary" or "text" mode on
systems where the run-time libraries distinguish between binary and text
files. If FILEHANDLE is an expression, the value is taken as the name of
the filehandle. Returns true on success, otherwise it returns "undef" and
sets $! (errno).

On some systems (in general, DOS and Windows-based systems) binmode() is
necessary when you’re not working with a text file. For the sake of porta-
bility it is a good idea to always use it when appropriate, and to never
use it when it isn’t appropriate. Also, people can set their I/O to be by
default UTF-8 encoded Unicode, not bytes.

In other words: regardless of platform, use binmode() on binary data, like
for example images.

If LAYER is present it is a single string, but may contain multiple
directives. The directives alter the behaviour of the file handle. When
LAYER is present using binmode on text file makes sense.

If LAYER is omitted or specified as ":raw" the filehandle is made suitable
for passing binary data. This includes turning off possible CRLF transla-
tion and marking it as bytes (as opposed to Unicode characters). Note
that, despite what may be implied in "Programming Perl" (the Camel) or
elsewhere, ":raw" is not the simply inverse of ":crlf" -- other layers
which would affect binary nature of the stream are also disabled. See Per-
lIO, perlrun and the discussion about the PERLIO environment variable.

The ":bytes", ":crlf", and ":utf8", and any other directives of the form
":...", are called I/O layers. The "open" pragma can be used to establish
default I/O layers. See open.

The LAYER parameter of the binmode() function is described as "DISCIPLINE"
in "Programming Perl, 3rd Edition". However, since the publishing of this
book, by many known as "Camel III", the consensus of the naming of this
functionality has moved from "discipline" to "layer". All documentation of
this version of Perl therefore refers to "layers" rather than to "disci-
plines". Now back to the regularly scheduled documentation...

To mark FILEHANDLE as UTF-8, use ":utf8".

In general, binmode() should be called after open() but before any I/O is
done on the filehandle. Calling binmode() will normally flush any pending
buffered output data (and perhaps pending input data) on the handle. An
exception to this is the ":encoding" layer that changes the default charac-
ter encoding of the handle, see open. The ":encoding" layer sometimes
needs to be called in mid-stream, and it doesn’t flush the stream. The
":encoding" also implicitly pushes on top of itself the ":utf8" layer
because internally Perl will operate on UTF-8 encoded Unicode characters.

The operating system, device drivers, C libraries, and Perl run-time system
all work together to let the programmer treat a single character ("\n") as
the line terminator, irrespective of the external representation. On many
operating systems, the native text file representation matches the internal
representation, but on some platforms the external representation of "\n"
is made up of more than one character.

Mac OS, all variants of Unix, and Stream_LF files on VMS use a single char-
acter to end each line in the external representation of text (even though
that single character is CARRIAGE RETURN on Mac OS and LINE FEED on Unix
and most VMS files). In other systems like OS/2, DOS and the various fla-
vors of MS-Windows your program sees a "\n" as a simple "\cJ", but what’s
stored in text files are the two characters "\cM\cJ". That means that, if
you don’t use binmode() on these systems, "\cM\cJ" sequences on disk will
be converted to "\n" on input, and any "\n" in your program will be con-
verted back to "\cM\cJ" on output. This is what you want for text files,
but it can be disastrous for binary files.

Another consequence of using binmode() (on some systems) is that special
end-of-file markers will be seen as part of the data stream. For systems
from the Microsoft family this means that if your binary data contains
"\cZ", the I/O subsystem will regard it as the end of the file, unless you
use binmode().

binmode() is not only important for readline() and print() operations, but
also when using read(), seek(), sysread(), syswrite() and tell() (see perl-
port for more details). See the $/ and "$\" variables in perlvar for how
to manually set your input and output line-termination sequences.

bless REF,CLASSNAME
bless REF
This function tells the thingy referenced by REF that it is now an object
in the CLASSNAME package. If CLASSNAME is omitted, the current package is
used. Because a "bless" is often the last thing in a constructor, it
returns the reference for convenience. Always use the two-argument version
if the function doing the blessing might be inherited by a derived class.
See perltoot and perlobj for more about the blessing (and blessings) of
objects.

Consider always blessing objects in CLASSNAMEs that are mixed case. Names-
paces with all lowercase names are considered reserved for Perl pragmata.
Builtin types have all uppercase names, so to prevent confusion, you may
wish to avoid such package names as well. Make sure that CLASSNAME is a
true value.

See "Perl Modules" in perlmod.

caller EXPR
caller Returns the context of the current subroutine call. In scalar context,
returns the caller’s package name if there is a caller, that is, if we’re
in a subroutine or "eval" or "require", and the undefined value otherwise.
In list context, returns

($package, $filename, $line) = caller;

With EXPR, it returns some extra information that the debugger uses to
print a stack trace. The value of EXPR indicates how many call frames to
go back before the current one.

($package, $filename, $line, $subroutine, $hasargs,
$wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);

Here $subroutine may be "(eval)" if the frame is not a subroutine call, but
an "eval". In such a case additional elements $evaltext and $is_require
are set: $is_require is true if the frame is created by a "require" or
"use" statement, $evaltext contains the text of the "eval EXPR" statement.
In particular, for an "eval BLOCK" statement, $filename is "(eval)", but
$evaltext is undefined. (Note also that each "use" statement creates a
"require" frame inside an "eval EXPR" frame.) $subroutine may also be
"(unknown)" if this particular subroutine happens to have been deleted from
the symbol table. $hasargs is true if a new instance of @_ was set up for
the frame. $hints and $bitmask contain pragmatic hints that the caller was
compiled with. The $hints and $bitmask values are subject to change
between versions of Perl, and are not meant for external use.

Furthermore, when called from within the DB package, caller returns more
detailed information: it sets the list variable @DB::args to be the argu-
ments with which the subroutine was invoked.

Be aware that the optimizer might have optimized call frames away before
"caller" had a chance to get the information. That means that caller(N)
might not return information about the call frame you expect it do, for "N
> 1". In particular, @DB::args might have information from the previous
time "caller" was called.

chdir EXPR
Changes the working directory to EXPR, if possible. If EXPR is omitted,
changes to the directory specified by $ENV{HOME}, if set; if not, changes
to the directory specified by $ENV{LOGDIR}. (Under VMS, the variable
$ENV{SYS$LOGIN} is also checked, and used if it is set.) If neither is set,
"chdir" does nothing. It returns true upon success, false otherwise. See
the example under "die".

chmod LIST
Changes the permissions of a list of files. The first element of the list
must be the numerical mode, which should probably be an octal number, and
which definitely should not a string of octal digits: 0644 is okay, ’0644’
is not. Returns the number of files successfully changed. See also "oct",
if all you have is a string.

$cnt = chmod 0755, ’foo’, ’bar’;
chmod 0755, @executables;
$mode = ’0644’; chmod $mode, ’foo’; # !!! sets mode to
# --w----r-T
$mode = ’0644’; chmod oct($mode), ’foo’; # this is better
$mode = 0644; chmod $mode, ’foo’; # this is best

You can also import the symbolic "S_I*" constants from the Fcntl module:

use Fcntl ’:mode’;

chmod S_IRWXU│S_IRGRP│S_IXGRP│S_IROTH│S_IXOTH, @executables;
# This is identical to the chmod 0755 of the above example.

chomp VARIABLE
chomp( LIST )
chomp This safer version of "chop" removes any trailing string that corresponds
to the current value of $/ (also known as $INPUT_RECORD_SEPARATOR in the
"English" module). It returns the total number of characters removed from
all its arguments. It’s often used to remove the newline from the end of
an input record when you’re worried that the final record may be missing
its newline. When in paragraph mode ("$/ = """), it removes all trailing
newlines from the string. When in slurp mode ("$/ = undef") or fixed-
length record mode ($/ is a reference to an integer or the like, see perl-
var) chomp() won’t remove anything. If VARIABLE is omitted, it chomps $_.
Example:

while (<>) {
chomp; # avoid \n on last field
@array = split(/:/);
# ...
}

If VARIABLE is a hash, it chomps the hash’s values, but not its keys.

You can actually chomp anything that’s an lvalue, including an assignment:

chomp($cwd = ‘pwd‘);
chomp($answer = <STDIN>);

If you chomp a list, each element is chomped, and the total number of char-
acters removed is returned.

If the "encoding" pragma is in scope then the lengths returned are calcu-
lated from the length of $/ in Unicode characters, which is not always the
same as the length of $/ in the native encoding.

Note that parentheses are necessary when you’re chomping anything that is
not a simple variable. This is because "chomp $cwd = ‘pwd‘;" is inter-
preted as "(chomp $cwd) = ‘pwd‘;", rather than as "chomp( $cwd = ‘pwd‘ )"
which you might expect. Similarly, "chomp $a, $b" is interpreted as
"chomp($a), $b" rather than as "chomp($a, $b)".

chop VARIABLE
chop( LIST )
chop Chops off the last character of a string and returns the character chopped.
It is much more efficient than "s/.$//s" because it neither scans nor
copies the string. If VARIABLE is omitted, chops $_. If VARIABLE is a
hash, it chops the hash’s values, but not its keys.

You can actually chop anything that’s an lvalue, including an assignment.

If you chop a list, each element is chopped. Only the value of the last
"chop" is returned.

Note that "chop" returns the last character. To return all but the last
character, use "substr($string, 0, -1)".

See also "keys", "values" and "sort".

eof FILEHANDLE
eof ()
eof Returns 1 if the next read on FILEHANDLE will return end of file, or if
FILEHANDLE is not open. FILEHANDLE may be an expression whose value gives
the real filehandle. (Note that this function actually reads a character
and then "ungetc"s it, so isn’t very useful in an interactive context.) Do
not read from a terminal file (or call "eof(FILEHANDLE)" on it) after end-
of-file is reached. File types such as terminals may lose the end-of-file
condition if you do.

An "eof" without an argument uses the last file read. Using "eof()" with
empty parentheses is very different. It refers to the pseudo file formed
from the files listed on the command line and accessed via the "<>" opera-
tor. Since "<>" isn’t explicitly opened, as a normal filehandle is, an
"eof()" before "<>" has been used will cause @ARGV to be examined to deter-
mine if input is available. Similarly, an "eof()" after "<>" has returned
end-of-file will assume you are processing another @ARGV list, and if you
haven’t set @ARGV, will read input from "STDIN"; see "I/O Operators" in
perlop.

In a "while (<>)" loop, "eof" or "eof(ARGV)" can be used to detect the end
of each file, "eof()" will only detect the end of the last file. Examples:

# reset line numbering on each input file
while (<>) {
next if /^\s*#/; # skip comments
print "$.\t$_";
} continue {
close ARGV if eof; # Not eof()!
}

# insert dashes just before last line of last file
while (<>) {
if (eof()) { # check for end of last file
print "--------------\n";
}
print;
last if eof(); # needed if we’re reading from a terminal
}

Practical hint: you almost never need to use "eof" in Perl, because the
input operators typically return "undef" when they run out of data, or if
there was an error.

eval EXPR
eval BLOCK
In the first form, the return value of EXPR is parsed and executed as if it
were a little Perl program. The value of the expression (which is itself
determined within scalar context) is first parsed, and if there weren’t any
errors, executed in the lexical context of the current Perl program, so
that any variable settings or subroutine and format definitions remain
afterwards. Note that the value is parsed every time the eval executes.
If EXPR is omitted, evaluates $_. This form is typically used to delay
parsing and subsequent execution of the text of EXPR until run time.

In the second form, the code within the BLOCK is parsed only once--at the
same time the code surrounding the eval itself was parsed--and executed
within the context of the current Perl program. This form is typically
used to trap exceptions more efficiently than the first (see below), while
also providing the benefit of checking the code within BLOCK at compile
time.

The final semicolon, if any, may be omitted from the value of EXPR or
within the BLOCK.

In both forms, the value returned is the value of the last expression eval-
uated inside the mini-program; a return statement may be also used, just as
with subroutines. The expression providing the return value is evaluated
in void, scalar, or list context, depending on the context of the eval
itself. See "wantarray" for more on how the evaluation context can be
determined.

If there is a syntax error or runtime error, or a "die" statement is exe-
cuted, an undefined value is returned by "eval", and $@ is set to the error
message. If there was no error, $@ is guaranteed to be a null string.
Beware that using "eval" neither silences perl from printing warnings to
STDERR, nor does it stuff the text of warning messages into $@. To do
either of those, you have to use the $SIG{__WARN__} facility, or turn off
warnings inside the BLOCK or EXPR using "no warnings ’all’". See "warn",
perlvar, warnings and perllexwarn.

Note that, because "eval" traps otherwise-fatal errors, it is useful for
determining whether a particular feature (such as "socket" or "symlink") is
implemented. It is also Perl’s exception trapping mechanism, where the die
operator is used to raise exceptions.

If the code to be executed doesn’t vary, you may use the eval-BLOCK form to
trap run-time errors without incurring the penalty of recompiling each
time. The error, if any, is still returned in $@. Examples:

# make divide-by-zero nonfatal
eval { $answer = $a / $b; }; warn $@ if $@;

# same thing, but less efficient
eval ’$answer = $a / $b’; warn $@ if $@;

# a compile-time error
eval { $answer = }; # WRONG

# a run-time error
eval ’$answer =’; # sets $@

Due to the current arguably broken state of "__DIE__" hooks, when using the
"eval{}" form as an exception trap in libraries, you may wish not to trig-
ger any "__DIE__" hooks that user code may have installed. You can use the
"local $SIG{__DIE__}" construct for this purpose, as shown in this example:

# a very private exception trap for divide-by-zero
eval { local $SIG{’__DIE__’}; $answer = $a / $b; };
warn $@ if $@;

This is especially significant, given that "__DIE__" hooks can call "die"
again, which has the effect of changing their error messages:

# __DIE__ hooks may modify error messages
{
local $SIG{’__DIE__’} =
sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
eval { die "foo lives here" };
print $@ if $@; # prints "bar lives here"
}

Because this promotes action at a distance, this counterintuitive behavior
may be fixed in a future release.

With an "eval", you should be especially careful to remember what’s being
looked at when:

eval $x; # CASE 1
eval "$x"; # CASE 2

eval ’$x’; # CASE 3
eval { $x }; # CASE 4

eval "\$$x++"; # CASE 5
$$x++; # CASE 6

Cases 1 and 2 above behave identically: they run the code contained in the
variable $x. (Although case 2 has misleading double quotes making the
reader wonder what else might be happening (nothing is).) Cases 3 and 4
likewise behave in the same way: they run the code ’$x’, which does nothing
but return the value of $x. (Case 4 is preferred for purely visual rea-
sons, but it also has the advantage of compiling at compile-time instead of
at run-time.) Case 5 is a place where normally you would like to use dou-
ble quotes, except that in this particular situation, you can just use sym-
bolic references instead, as in case 6.

"eval BLOCK" does not count as a loop, so the loop control statements
"next", "last", or "redo" cannot be used to leave or restart the block.

Note that as a very special case, an "eval ’’" executed within the "DB"
package doesn’t see the usual surrounding lexical scope, but rather the
scope of the first non-DB piece of code that called it. You don’t normally
need to worry about this unless you are writing a Perl debugger.

exec LIST
exec PROGRAM LIST
The "exec" function executes a system command and never returns-- use "sys-
tem" instead of "exec" if you want it to return. It fails and returns
false only if the command does not exist and it is executed directly
instead of via your system’s command shell (see below).

Since it’s a common mistake to use "exec" instead of "system", Perl warns
you if there is a following statement which isn’t "die", "warn", or "exit"
(if "-w" is set - but you always do that). If you really want to follow
an "exec" with some other statement, you can use one of these styles to
avoid the warning:

exec (’foo’) or print STDERR "couldn’t exec foo: $!";
{ exec (’foo’) }; print STDERR "couldn’t exec foo: $!";

If there is more than one argument in LIST, or if LIST is an array with
more than one value, calls execvp(3) with the arguments in LIST. If there
is only one scalar argument or an array with one element in it, the argu-
ment is checked for shell metacharacters, and if there are any, the entire
argument is passed to the system’s command shell for parsing (this is
"/bin/sh -c" on Unix platforms, but varies on other platforms). If there
are no shell metacharacters in the argument, it is split into words and
passed directly to "execvp", which is more efficient. Examples:

exec ’/bin/echo’, ’Your arguments are: ’, @ARGV;
exec "sort $outfile │ uniq";

If you don’t really want to execute the first argument, but want to lie to
the program you are executing about its own name, you can specify the pro-
gram you actually want to run as an "indirect object" (without a comma) in
front of the LIST. (This always forces interpretation of the LIST as a
multivalued list, even if there is only a single scalar in the list.)
Example:

$shell = ’/bin/csh’;
exec $shell ’-sh’; # pretend it’s a login shell

or, more directly,

exec {’/bin/csh’} ’-sh’; # pretend it’s a login shell

When the arguments get executed via the system shell, results will be sub-
ject to its quirks and capabilities. See "‘STRING‘" in perlop for details.

Using an indirect object with "exec" or "system" is also more secure. This
usage (which also works fine with system()) forces interpretation of the
arguments as a multivalued list, even if the list had just one argument.
That way you’re safe from the shell expanding wildcards or splitting up
words with whitespace in them.

@args = ( "echo surprise" );

exec @args; # subject to shell escapes
# if @args == 1
exec { $args[0] } @args; # safe even with one-arg list

The first version, the one without the indirect object, ran the echo pro-
gram, passing it "surprise" an argument. The second version didn’t--it
tried to run a program literally called "echo surprise", didn’t find it,
and set $? to a non-zero value indicating failure.

Beginning with v5.6.0, Perl will attempt to flush all files opened for out-
put before the exec, but this may not be supported on some platforms (see
perlport). To be safe, you may need to set $│ ($AUTOFLUSH in English) or
call the "autoflush()" method of "IO::Handle" on any open handles in order
to avoid lost output.

Note that "exec" will not call your "END" blocks, nor will it call any
"DESTROY" methods in your objects.

exists EXPR
Given an expression that specifies a hash element or array element, returns
true if the specified element in the hash or array has ever been initial-
ized, even if the corresponding value is undefined. The element is not
autovivified if it doesn’t exist.

print "Exists\n" if exists $hash{$key};
print "Defined\n" if defined $hash{$key};
print "True\n" if $hash{$key};

print "Exists\n" if exists $array[$index];
print "Defined\n" if defined $array[$index];
print "True\n" if $array[$index];

A hash or array element can be true only if it’s defined, and defined if it
exists, but the reverse doesn’t necessarily hold true.

Given an expression that specifies the name of a subroutine, returns true
if the specified subroutine has ever been declared, even if it is
undefined. Mentioning a subroutine name for exists or defined does not
count as declaring it. Note that a subroutine which does not exist may
still be callable: its package may have an "AUTOLOAD" method that makes it
spring into existence the first time that it is called -- see perlsub.

print "Exists\n" if exists &subroutine;
print "Defined\n" if defined &subroutine;

Note that the EXPR can be arbitrarily complicated as long as the final
operation is a hash or array key lookup or subroutine name:

if (exists $ref->{A}->{B}->{$key}) { }
if (exists $hash{A}{B}{$key}) { }

if (exists $ref->{A}->{B}->[$ix]) { }
if (exists $hash{A}{B}[$ix]) { }

if (exists &{$ref->{A}{B}{$key}}) { }

Although the deepest nested array or hash will not spring into existence
just because its existence was tested, any intervening ones will. Thus
"$ref->{"A"}" and "$ref->{"A"}->{"B"}" will spring into existence due to
the existence test for the $key element above. This happens anywhere the
arrow operator is used, including even:

undef $ref;
if (exists $ref->{"Some key"}) { }
print $ref; # prints HASH(0x80d3d5c)

This surprising autovivification in what does not at first--or even sec-
ond--glance appear to be an lvalue context may be fixed in a future
release.

See "Pseudo-hashes: Using an array as a hash" in perlref for specifics on
how exists() acts when used on a pseudo-hash.

Use of a subroutine call, rather than a subroutine name, as an argument to
exists() is an error.

exists &sub; # OK
exists &sub(); # Error

exit EXPR
Evaluates EXPR and exits immediately with that value. Example:

$ans = <STDIN>;
exit 0 if $ans =~ /^[Xx]/;

See also "die". If EXPR is omitted, exits with 0 status. The only univer-
sally recognized values for EXPR are 0 for success and 1 for error; other
values are subject to interpretation depending on the environment in which
the Perl program is running. For example, exiting 69 (EX_UNAVAILABLE) from
a sendmail incoming-mail filter will cause the mailer to return the item
undelivered, but that’s not true everywhere.

Don’t use "exit" to abort a subroutine if there’s any chance that someone
might want to trap whatever error happened. Use "die" instead, which can
be trapped by an "eval".

The exit() function does not always exit immediately. It calls any defined
"END" routines first, but these "END" routines may not themselves abort the
exit. Likewise any object destructors that need to be called are called
before the real exit. If this is a problem, you can call
"POSIX:_exit($status)" to avoid END and destructor processing. See perlmod
for details.

exp EXPR
exp Returns e (the natural logarithm base) to the power of EXPR. If EXPR is
omitted, gives "exp($_)".

fcntl FILEHANDLE,FUNCTION,SCALAR
Implements the fcntl(2) function. You’ll probably have to say

use Fcntl;

first to get the correct constant definitions. Argument processing and
value return works just like "ioctl" below. For example:

use Fcntl;
fcntl($filehandle, F_GETFL, $packed_return_buffer)
or die "can’t fcntl F_GETFL: $!";

You don’t have to check for "defined" on the return from "fcntl". Like
"ioctl", it maps a 0 return from the system call into "0 but true" in Perl.
This string is true in boolean context and 0 in numeric context. It is
also exempt from the normal -w warnings on improper numeric conversions.

Note that "fcntl" will produce a fatal error if used on a machine that
doesn’t implement fcntl(2). See the Fcntl module or your fcntl(2) manpage
to learn what functions are available on your system.

Here’s an example of setting a filehandle named "REMOTE" to be non-blocking
at the system level. You’ll have to negotiate $│ on your own, though.

use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);

$flags = fcntl(REMOTE, F_GETFL, 0)
or die "Can’t get flags for the socket: $!\n";

$flags = fcntl(REMOTE, F_SETFL, $flags │ O_NONBLOCK)
or die "Can’t set flags for the socket: $!\n";

fileno FILEHANDLE
Returns the file descriptor for a filehandle, or undefined if the filehan-
dle is not open. This is mainly useful for constructing bitmaps for
"select" and low-level POSIX tty-handling operations. If FILEHANDLE is an
expression, the value is taken as an indirect filehandle, generally its
name.

You can use this to find out whether two handles refer to the same underly-
ing descriptor:

if (fileno(THIS) == fileno(THAT)) {
print "THIS and THAT are dups\n";
}

(Filehandles connected to memory objects via new features of "open" may
return undefined even though they are open.)

flock FILEHANDLE,OPERATION
Calls flock(2), or an emulation of it, on FILEHANDLE. Returns true for
success, false on failure. Produces a fatal error if used on a machine
that doesn’t implement flock(2), fcntl(2) locking, or lockf(3). "flock" is
Perl’s portable file locking interface, although it locks only entire
files, not records.

Two potentially non-obvious but traditional "flock" semantics are that it
waits indefinitely until the lock is granted, and that its locks merely
advisory. Such discretionary locks are more flexible, but offer fewer
guarantees. This means that files locked with "flock" may be modified by
programs that do not also use "flock". See perlport, your port’s specific
documentation, or your system-specific local manpages for details. It’s
best to assume traditional behavior if you’re writing portable programs.
(But if you’re not, you should as always feel perfectly free to write for
your own system’s idiosyncrasies (sometimes called "features"). Slavish
adherence to portability concerns shouldn’t get in the way of your getting
your job done.)

OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
LOCK_NB. These constants are traditionally valued 1, 2, 8 and 4, but you
can use the symbolic names if you import them from the Fcntl module, either
individually, or as a group using the ’:flock’ tag. LOCK_SH requests a
shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN releases a
previously requested lock. If LOCK_NB is bitwise-or’ed with LOCK_SH or
LOCK_EX then "flock" will return immediately rather than blocking waiting
for the lock (check the return status to see if you got it).

To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
before locking or unlocking it.

Note that the emulation built with lockf(3) doesn’t provide shared locks,
and it requires that FILEHANDLE be open with write intent. These are the
semantics that lockf(3) implements. Most if not all systems implement
lockf(3) in terms of fcntl(2) locking, though, so the differing semantics
shouldn’t bite too many people.

Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE be
open with read intent to use LOCK_SH and requires that it be open with
write intent to use LOCK_EX.

Note also that some versions of "flock" cannot lock things over the net-
work; you would need to use the more system-specific "fcntl" for that. If
you like you can force Perl to ignore your system’s flock(2) function, and
so provide its own fcntl(2)-based emulation, by passing the switch
"-Ud_flock" to the Configure program when you configure perl.

Here’s a mailbox appender for BSD systems.

use Fcntl ’:flock’; # import LOCK_* constants

sub lock {
flock(MBOX,LOCK_EX);
# and, in case someone appended
# while we were waiting...
seek(MBOX, 0, 2);
}

sub unlock {
flock(MBOX,LOCK_UN);
}

open(MBOX, ">>/usr/spool/mail/$ENV{’USER’}")
or die "Can’t open mailbox: $!";

lock();
print MBOX $msg,"\n\n";
unlock();

On systems that support a real flock(), locks are inherited across fork()
calls, whereas those that must resort to the more capricious fcntl() func-
tion lose the locks, making it harder to write servers.

See also DB_File for other flock() examples.

fork Does a fork(2) system call to create a new process running the same program
at the same point. It returns the child pid to the parent process, 0 to
the child process, or "undef" if the fork is unsuccessful. File descrip-
tors (and sometimes locks on those descriptors) are shared, while every-
thing else is copied. On most systems supporting fork(), great care has
gone into making it extremely efficient (for example, using copy-on-write
technology on data pages), making it the dominant paradigm for multitasking
over the last few decades.

Beginning with v5.6.0, Perl will attempt to flush all files opened for out-
put before forking the child process, but this may not be supported on some
platforms (see perlport). To be safe, you may need to set $│ ($AUTOFLUSH
in English) or call the "autoflush()" method of "IO::Handle" on any open
handles in order to avoid duplicate output.

If you "fork" without ever waiting on your children, you will accumulate
zombies. On some systems, you can avoid this by setting $SIG{CHLD} to
"IGNORE". See also perlipc for more examples of forking and reaping mori-
bund children.

Note that if your forked child inherits system file descriptors like STDIN
and STDOUT that are actually connected by a pipe or socket, even if you
exit, then the remote server (such as, say, a CGI script or a backgrounded
job launched from a remote shell) won’t think you’re done. You should
reopen those to /dev/null if it’s any issue.

format Declare a picture format for use by the "write" function. For example:

format Something =
Test: @<<<<<<<< @│││││ @>>>>>
$str, $%, ’$’ . int($num)
.

$str = "widget";
$num = $cost/$quantity;
$~ = ’Something’;
write;

See perlform for many details and examples.

formline PICTURE,LIST
This is an internal function used by "format"s, though you may call it,
too. It formats (see perlform) a list of values according to the contents
of PICTURE, placing the output into the format output accumulator, $^A (or
$ACCUMULATOR in English). Eventually, when a "write" is done, the contents
of $^A are written to some filehandle, but you could also read $^A yourself
and then set $^A back to "". Note that a format typically does one "form-
line" per line of form, but the "formline" function itself doesn’t care how
many newlines are embedded in the PICTURE. This means that the "~" and
"~~" tokens will treat the entire PICTURE as a single line. You may there-
fore need to use multiple formlines to implement a single record format,
just like the format compiler.

Be careful if you put double quotes around the picture, because an "@"
character may be taken to mean the beginning of an array name. "formline"
always returns true. See perlform for other examples.

getc FILEHANDLE
getc Returns the next character from the input file attached to FILEHANDLE, or
the undefined value at end of file, or if there was an error (in the latter
case $! is set). If FILEHANDLE is omitted, reads from STDIN. This is not
particularly efficient. However, it cannot be used by itself to fetch sin-
gle characters without waiting for the user to hit enter. For that, try
something more like:

if ($BSD_STYLE) {
system "stty cbreak </dev/tty >/dev/tty 2>&1";
}
else {
system "stty", ’-icanon’, ’eol’, "\001";
}

$key = getc(STDIN);

if ($BSD_STYLE) {
system "stty -cbreak </dev/tty >/dev/tty 2>&1";
}
else {
system "stty", ’icanon’, ’eol’, ’^@’; # ASCII null
}
print "\n";

Determination of whether $BSD_STYLE should be set is left as an exercise to
the reader.

The "POSIX::getattr" function can do this more portably on systems purport-
ing POSIX compliance. See also the "Term::ReadKey" module from your near-
est CPAN site; details on CPAN can be found on "CPAN" in perlmodlib.

getlogin
Implements the C library function of the same name, which on most systems
returns the current login from /etc/utmp, if any. If null, use "getpwuid".

$login = getlogin ││ getpwuid($<) ││ "Kilroy";

Do not consider "getlogin" for authentication: it is not as secure as "get-
pwuid".

getpeername SOCKET
Returns the packed sockaddr address of other end of the SOCKET connection.

use Socket;
$hersockaddr = getpeername(SOCK);
($port, $iaddr) = sockaddr_in($hersockaddr);
$herhostname = gethostbyaddr($iaddr, AF_INET);
$herstraddr = inet_ntoa($iaddr);

getpgrp PID
Returns the current process group for the specified PID. Use a PID of 0 to
get the current process group for the current process. Will raise an
exception if used on a machine that doesn’t implement getpgrp(2). If PID
is omitted, returns process group of current process. Note that the POSIX
version of "getpgrp" does not accept a PID argument, so only "PID==0" is
truly portable.

getppid Returns the process id of the parent process.

Note for Linux users: on Linux, the C functions "getpid()" and "getppid()"
return different values from different threads. In order to be portable,
this behavior is not reflected by the perl-level function "getppid()", that
returns a consistent value across threads. If you want to call the underly-
ing "getppid()", you may use the CPAN module "Linux::Pid".

getpriority WHICH,WHO
Returns the current priority for a process, a process group, or a user.
(See getpriority(2).) Will raise a fatal exception if used on a machine
that doesn’t implement getpriority(2).

getpwnam NAME
getgrnam NAME
gethostbyname NAME
getnetbyname NAME
getprotobyname NAME
getpwuid UID
getgrgid GID
getservbyname NAME,PROTO
gethostbyaddr ADDR,ADDRTYPE
getnetbyaddr ADDR,ADDRTYPE
getprotobynumber NUMBER
getservbyport PORT,PROTO
getpwent
getgrent
gethostent
getnetent
getprotoent
getservent
setpwent
setgrent
sethostent STAYOPEN
setnetent STAYOPEN
setprotoent STAYOPEN
setservent STAYOPEN
endpwent
endgrent
endhostent
endnetent
endprotoent
endservent
These routines perform the same functions as their counterparts in the sys-
tem library. In list context, the return values from the various get
routines are as follows:

($name,$passwd,$uid,$gid,
$quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
($name,$passwd,$gid,$members) = getgr*
($name,$aliases,$addrtype,$length,@addrs) = gethost*
($name,$aliases,$addrtype,$net) = getnet*
($name,$aliases,$proto) = getproto*
($name,$aliases,$port,$proto) = getserv*

(If the entry doesn’t exist you get a null list.)

The exact meaning of the $gcos field varies but it usually contains the
real name of the user (as opposed to the login name) and other information
pertaining to the user. Beware, however, that in many system users are
able to change this information and therefore it cannot be trusted and
therefore the $gcos is tainted (see perlsec). The $passwd and $shell,
user’s encrypted password and login shell, are also tainted, because of the
same reason.

In scalar context, you get the name, unless the function was a lookup by
name, in which case you get the other thing, whatever it is. (If the entry
doesn’t exist you get the undefined value.) For example:

$uid = getpwnam($name);
$name = getpwuid($num);
$name = getpwent();
$gid = getgrnam($name);
$name = getgrgid($num);
$name = getgrent();
#etc.

In getpw*() the fields $quota, $comment, and $expire are special cases in
the sense that in many systems they are unsupported. If the $quota is
unsupported, it is an empty scalar. If it is supported, it usually encodes
the disk quota. If the $comment field is unsupported, it is an empty
scalar. If it is supported it usually encodes some administrative comment
about the user. In some systems the $quota field may be $change or $age,
fields that have to do with password aging. In some systems the $comment
field may be $class. The $expire field, if present, encodes the expiration
period of the account or the password. For the availability and the exact
meaning of these fields in your system, please consult your getpwnam(3)
documentation and your pwd.h file. You can also find out from within Perl
what your $quota and $comment fields mean and whether you have the $expire
field by using the "Config" module and the values "d_pwquota", "d_pwage",
"d_pwchange", "d_pwcomment", and "d_pwexpire". Shadow password files are
only supported if your vendor has implemented them in the intuitive fashion
that calling the regular C library routines gets the shadow versions if
you’re running under privilege or if there exists the shadow(3) functions
as found in System V ( this includes Solaris and Linux.) Those systems
which implement a proprietary shadow password facility are unlikely to be
supported.

The $members value returned by getgr*() is a space separated list of the
login names of the members of the group.

For the gethost*() functions, if the "h_errno" variable is supported in C,
it will be returned to you via $? if the function call fails. The @addrs
value returned by a successful call is a list of the raw addresses returned
by the corresponding system library call. In the Internet domain, each
address is four bytes long and you can unpack it by saying something like:

($a,$b,$c,$d) = unpack(’C4’,$addr[0]);

The Socket library makes this slightly easier:

use Socket;
$iaddr = inet_aton("127.1"); # or whatever address
$name = gethostbyaddr($iaddr, AF_INET);

# or going the other way
$straddr = inet_ntoa($iaddr);

If you get tired of remembering which element of the return list contains
which return value, by-name interfaces are provided in standard modules:
"File::stat", "Net::hostent", "Net::netent", "Net::protoent", "Net::ser-
vent", "Time::gmtime", "Time::localtime", and "User::grent". These over-
ride the normal built-ins, supplying versions that return objects with the
appropriate names for each field. For example:

use File::stat;
use User::pwent;
$is_his = (stat($filename)->uid == pwent($whoever)->uid);

Even though it looks like they’re the same method calls (uid), they aren’t,
because a "File::stat" object is different from a "User::pwent" object.

getsockname SOCKET
Returns the packed sockaddr address of this end of the SOCKET connection,
in case you don’t know the address because you have several different IPs
that the connection might have come in on.

use Socket;
$mysockaddr = getsockname(SOCK);
($port, $myaddr) = sockaddr_in($mysockaddr);
printf "Connect to %s [%s]\n",
scalar gethostbyaddr($myaddr, AF_INET),
inet_ntoa($myaddr);

getsockopt SOCKET,LEVEL,OPTNAME
Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
Options may exist at multiple protocol levels depending on the socket type,
but at least the uppermost socket level SOL_SOCKET (defined in the "Socket"
module) will exist. To query options at another level the protocol number
of the appropriate protocol controlling the option should be supplied. For
example, to indicate that an option is to be interpreted by the TCP proto-
col, LEVEL should be set to the protocol number of TCP, which you can get
using getprotobyname.

The call returns a packed string representing the requested socket option,
or "undef" if there is an error (the error reason will be in $!). What
exactly is in the packed string depends in the LEVEL and OPTNAME, consult
your system documentation for details. A very common case however is that
the option is an integer, in which case the result will be an packed inte-
ger which you can decode using unpack with the "i" (or "I") format.

An example testing if Nagle’s algorithm is turned on on a socket:

use Socket;

defined(my $tcp = getprotobyname("tcp"))
or die "Could not determine the protocol number for tcp";
# my $tcp = Socket::IPPROTO_TCP; # Alternative
my $packed = getsockopt($socket, $tcp, Socket::TCP_NODELAY)
or die "Could not query TCP_NODELAY SOCKEt option: $!";
my $nodelay = unpack("I", $packed);
print "Nagle’s algorithm is turned ", $nodelay ? "off\n" : "on\n";

glob EXPR
glob In list context, returns a (possibly empty) list of filename expansions on
the value of EXPR such as the standard Unix shell /bin/csh would do. In
scalar context, glob iterates through such filename expansions, returning
undef when the list is exhausted. This is the internal function implement-
ing the "<*.c>" operator, but you can use it directly. If EXPR is omitted,
$_ is used. The "<*.c>" operator is discussed in more detail in "I/O Oper-
ators" in perlop.

Beginning with v5.6.0, this operator is implemented using the standard
"File::Glob" extension. See File::Glob for details.

gmtime EXPR
Converts a time as returned by the time function to an 8-element list with
the time localized for the standard Greenwich time zone. Typically used as
follows:

# 0 1 2 3 4 5 6 7
($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
gmtime(time);

All list elements are numeric, and come straight out of the C ‘struct tm’.
$sec, $min, and $hour are the seconds, minutes, and hours of the specified
time. $mday is the day of the month, and $mon is the month itself, in the
range 0..11 with 0 indicating January and 11 indicating December. $year is
the number of years since 1900. That is, $year is 123 in year 2023. $wday
is the day of the week, with 0 indicating Sunday and 3 indicating Wednes-
day. $yday is the day of the year, in the range 0..364 (or 0..365 in leap
years.)

Note that the $year element is not simply the last two digits of the year.
If you assume it is, then you create non-Y2K-compliant programs--and you
wouldn’t want to do that, would you?

The proper way to get a complete 4-digit year is simply:

$year += 1900;

And to get the last two digits of the year (e.g., ’01’ in 2001) do:

$year = sprintf("%02d", $year % 100);

If EXPR is omitted, "gmtime()" uses the current time ("gmtime(time)").

In scalar context, "gmtime()" returns the ctime(3) value:

$now_string = gmtime; # e.g., "Thu Oct 13 04:54:34 1994"

If you need local time instead of GMT use the "localtime" builtin. See
also the "timegm" function provided by the "Time::Local" module, and the
strftime(3) and mktime(3) functions available via the POSIX module.

This scalar value is not locale dependent (see perllocale), but is instead
a Perl builtin. To get somewhat similar but locale dependent date strings,
see the example in "localtime".

goto LABEL
goto EXPR
goto &NAME
The "goto-LABEL" form finds the statement labeled with LABEL and resumes
execution there. It may not be used to go into any construct that requires
initialization, such as a subroutine or a "foreach" loop. It also can’t be
used to go into a construct that is optimized away, or to get out of a
block or subroutine given to "sort". It can be used to go almost anywhere
else within the dynamic scope, including out of subroutines, but it’s usu-
ally better to use some other construct such as "last" or "die". The
author of Perl has never felt the need to use this form of "goto" (in Perl,
that is--C is another matter). (The difference being that C does not offer
named loops combined with loop control. Perl does, and this replaces most
structured uses of "goto" in other languages.)

The "goto-EXPR" form expects a label name, whose scope will be resolved
dynamically. This allows for computed "goto"s per FORTRAN, but isn’t nec-
essarily recommended if you’re optimizing for maintainability:

goto ("FOO", "BAR", "GLARCH")[$i];

The "goto-&NAME" form is quite different from the other forms of "goto".
In fact, it isn’t a goto in the normal sense at all, and doesn’t have the
stigma associated with other gotos. Instead, it exits the current subrou-
tine (losing any changes set by local()) and immediately calls in its place
the named subroutine using the current value of @_. This is used by
"AUTOLOAD" subroutines that wish to load another subroutine and then pre-
tend that the other subroutine had been called in the first place (except
that any modifications to @_ in the current subroutine are propagated to
the other subroutine.) After the "goto", not even "caller" will be able to
tell that this routine was called first.

NAME needn’t be the name of a subroutine; it can be a scalar variable con-
taining a code reference, or a block which evaluates to a code reference.

grep BLOCK LIST
grep EXPR,LIST
This is similar in spirit to, but not the same as, grep(1) and its rela-
tives. In particular, it is not limited to using regular expressions.

Evaluates the BLOCK or EXPR for each element of LIST (locally setting $_ to
each element) and returns the list value consisting of those elements for
which the expression evaluated to true. In scalar context, returns the
number of times the expression was true.

@foo = grep(!/^#/, @bar); # weed out comments

or equivalently,

@foo = grep {!/^#/} @bar; # weed out comments

Note that $_ is an alias to the list value, so it can be used to modify the
elements of the LIST. While this is useful and supported, it can cause
bizarre results if the elements of LIST are not variables. Similarly, grep
returns aliases into the original list, much as a for loop’s index variable
aliases the list elements. That is, modifying an element of a list
returned by grep (for example, in a "foreach", "map" or another "grep")
actually modifies the element in the original list. This is usually some-
thing to be avoided when writing clear code.

See also "map" for a list composed of the results of the BLOCK or EXPR.

hex EXPR
hex Interprets EXPR as a hex string and returns the corresponding value. (To
convert strings that might start with either 0, 0x, or 0b, see "oct".) If
EXPR is omitted, uses $_.

print hex ’0xAf’; # prints ’175’
print hex ’aF’; # same

Hex strings may only represent integers. Strings that would cause integer
overflow trigger a warning. Leading whitespace is not stripped, unlike
oct().

import There is no builtin "import" function. It is just an ordinary method (sub-
routine) defined (or inherited) by modules that wish to export names to
another module. The "use" function calls the "import" method for the pack-
age used. See also "use", perlmod, and Exporter.

index STR,SUBSTR,POSITION
index STR,SUBSTR
The index function searches for one string within another, but without the
wildcard-like behavior of a full regular-expression pattern match. It
returns the position of the first occurrence of SUBSTR in STR at or after
POSITION. If POSITION is omitted, starts searching from the beginning of
the string. The return value is based at 0 (or whatever you’ve set the $[
variable to--but don’t do that). If the substring is not found, returns
one less than the base, ordinarily "-1".

int EXPR
int Returns the integer portion of EXPR. If EXPR is omitted, uses $_. You
should not use this function for rounding: one because it truncates towards
0, and two because machine representations of floating point numbers can
sometimes produce counterintuitive results. For example,
"int(-6.725/0.025)" produces -268 rather than the correct -269; that’s
because it’s really more like -268.99999999999994315658 instead. Usually,
the "sprintf", "printf", or the "POSIX::floor" and "POSIX::ceil" functions
will serve you better than will int().

ioctl FILEHANDLE,FUNCTION,SCALAR
Implements the ioctl(2) function. You’ll probably first have to say

require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph

to get the correct function definitions. If ioctl.ph doesn’t exist or
doesn’t have the correct definitions you’ll have to roll your own, based on
your C header files such as <sys/ioctl.h>. (There is a Perl script called
h2ph that comes with the Perl kit that may help you in this, but it’s non-
trivial.) SCALAR will be read and/or written depending on the FUNCTION--a
pointer to the string value of SCALAR will be passed as the third argument
of the actual "ioctl" call. (If SCALAR has no string value but does have a
numeric value, that value will be passed rather than a pointer to the
string value. To guarantee this to be true, add a 0 to the scalar before
using it.) The "pack" and "unpack" functions may be needed to manipulate
the values of structures used by "ioctl".

The return value of "ioctl" (and "fcntl") is as follows:

if OS returns: then Perl returns:
-1 undefined value
0 string "0 but true"
anything else that number

Thus Perl returns true on success and false on failure, yet you can still
easily determine the actual value returned by the operating system:

$retval = ioctl(...) ││ -1;
printf "System returned %d\n", $retval;

The special string "0 but true" is exempt from -w complaints about improper
numeric conversions.

join EXPR,LIST
Joins the separate strings of LIST into a single string with fields sepa-
rated by the value of EXPR, and returns that new string. Example:

$rec = join(’:’, $login,$passwd,$uid,$gid,$gcos,$home,$shell);

Beware that unlike "split", "join" doesn’t take a pattern as its first
argument. Compare "split".

keys HASH
Returns a list consisting of all the keys of the named hash. (In scalar
context, returns the number of keys.)

The keys are returned in an apparently random order. The actual random
order is subject to change in future versions of perl, but it is guaranteed
to be the same order as either the "values" or "each" function produces
(given that the hash has not been modified). Since Perl 5.8.1 the ordering
is different even between different runs of Perl for security reasons (see
"Algorithmic Complexity Attacks" in perlsec).

As a side effect, calling keys() resets the HASH’s internal iterator, see
"each". (In particular, calling keys() in void context resets the iterator
with no other overhead.)

Here is yet another way to print your environment:

@keys = keys %ENV;
@values = values %ENV;
while (@keys) {
print pop(@keys), ’=’, pop(@values), "\n";
}

or how about sorted by key:

foreach $key (sort(keys %ENV)) {
print $key, ’=’, $ENV{$key}, "\n";
}

The returned values are copies of the original keys in the hash, so modify-
ing them will not affect the original hash. Compare "values".

To sort a hash by value, you’ll need to use a "sort" function. Here’s a
descending numeric sort of a hash by its values:

foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
printf "%4d %s\n", $hash{$key}, $key;
}

As an lvalue "keys" allows you to increase the number of hash buckets allo-
cated for the given hash. This can gain you a measure of efficiency if you
know the hash is going to get big. (This is similar to pre-extending an
array by assigning a larger number to $#array.) If you say

keys %hash = 200;

then %hash will have at least 200 buckets allocated for it--256 of them, in
fact, since it rounds up to the next power of two. These buckets will be
retained even if you do "%hash = ()", use "undef %hash" if you want to free
the storage while %hash is still in scope. You can’t shrink the number of
buckets allocated for the hash using "keys" in this way (but you needn’t
worry about doing this by accident, as trying has no effect).